HCenc Question

[Maikeru-sama]

Do you have to use an ini file or can you actually pass the hcenc.exe the arguments similar to FFMPeg or Quenc?

I looked in the HCenc folder but there was no documentation about this. If anyone knows where documentation can be found for the HCenc CLI, I would greatly appreciate it if you could post it here.

Thanks

[gadgetguy]

Check the "misc" folder under your HC install for the documentation (HC[version number].pdf)that explains the command options. Personally I find it easier to use an ini, but the command line options are there.

[freebird73717]

command line option
-noini
don't process the default HC.ini file

[Maikeru-sama]

Thanks, that was exactly what I was looking for.

[AlanHK]

Here's a couple of batch files where everything is specced on the command line:

Two pass: the AVS files and rate are set in the file

set rate=3221
set ar=16:9
::set ar=4:3

set choice=
set /p choice=Run encode? y/n     
if not '%choice%'=='y' exit

set hc=P:\HCenc\HCenc_023
set mpgd=s:\mpg\

for %%A in (
408.avs
409.avs
410.avs
) do  (
%hc% -i %%~fA -o %mpgd%%%~nA.m2v -b %rate%  -aspectratio %ar%  -pulldown -profile best -matrix qlb -frames all -noini -2pass -maxbitrate 8000 -log %%~dpAhenc.log
call avsaften %%~fA
move %%~dpnA.ac3 %mpgd%
)

And this uses CQ, single pass, mode: filesize is a bit unpredictable, but excellent results and obviously faster:

@echo off
echo: input AVS files
echo: output m2v at constant Q and AC3

set CQrate=4.5
set ar=16:9
::set ar=4:3

set choice=
set /p choice=Run encode on %1 %2 %3? y/n     
if not '%choice%'=='y' exit

set hc=P:\HCenc\HCenc_023
set mpgd=s:\mpg\

:LOOP
for %%A in (
%1
) do (
%hc% -i %%~fA -o %mpgd%%%~nA.m2v -aspectratio %ar%  -pulldown -profile best -matrix qlb -frames all -cq_maxbitrate %CQrate% -maxbitrate 8000
call avsaften %%~fA
move %%~dpnA.ac3 %mpgd%
)
SHIFT
@if %1X==X goto END
@goto LOOP

:END

These both use avsaften, which pipes the audio from the AVS into Aften to make AC3:

@echo avsaften avsfile.avs
@echo audio from avs files and convert to AC3
@echo uses wavi and aften

@if %1X==X goto ALL

:LOOP
for %%I in (%1) do (
wavi %%I - | p:\aften\aften.exe -b 128 -s 1 -w 45 -dnorm 27 - %%~nI.ac3
)

SHIFT
@if %1X==X goto END
@goto LOOP

:ALL
for %%I in (*.avs) do (
wavi %%I - | p:\aften\aften.exe -b 128 -s 1 -w 45 -dnorm 27 - %%~nI.ac3
)

:END

[freebird73717]

If I remember correctly, AlanHK weren't you the one who requested the noini feature to Hank315 in the first place? I seem to remember that in one of the hc threads on doom9.

[AlanHK]

If I remember correctly, AlanHK weren't you the one who requested the noini feature to Hank315 in the first place? I seem to remember that in one of the hc threads on doom9.

I think so. I mentioned that some settings in the INI file could override those on the command line, so that switch prevents that problem.
And a couple of other things could not be set at all on the command line in earlier version, but now it's got all the features.

So now I can just use or amend one batch file for each job and not have to keep track of INI files.