HDTV broadcast on DVD

[soothsayer]

What authoring software would you use and how would you do it? I have the Nero burning rom suite but no Nero Vision Express. I'm an avid golfer and want to capture some on DVD. I understand I'm going from 1080i to 480i and that I can't preserve the quality. Is there any freeware?

[manono]

Hi-

I'm having trouble understanding just exactly what you want to do. If you're making compliant DVDs for playback in standard DVD players, then it has to be resized to 720x480/576 and reencoded anyway, and any authoring program will accept the result.

If you're keeping it Hi-Def, then if it's AVI, WMV, MPEG-2, or TS, the DVD/MPEG-4 players with the new Sigma Designs chipset can play them:

https://www.videohelp.com/dvdplayers?chipset=Sigma%20EM8620L

Maybe I'm misunderstanding, though.

[dphirschler]

AviSynth can help. Here is my script:

# HDTV .ts conversion (1920x1080i)
#
# First load the .ts file into dgIndex and save project.
# This will give you a .d2v file and an .ac3 file.
# Then load the .d2v file using the below script.
# Remember any cuts you make in the video will de-synch
# the audio.

loadplugin("C:\Program Files\AviSynth 2.5\plugins\MPEGDecoder.dll")

vNTSC=MPEG2source("c:\video\work\bonjovi.d2v").cropbottom(8)


#return v #full HD resolution
return v720x480i(vNTSC)
#return v720x480p30(vNTSC)

# Converts 1920x1080i to 720x480i anamorphic
function v720x480i(v)
{
	# deinterlace the video
	v=bob(v) #Separate fields and interpolate them to full height

	# resize and reinterlace
	v=v.BilinearResize(720,480)
	#v=v.SeparateFields.SelectEvery(4,0,3) #even field first (BFF)
	v=v.SeparateFields.SelectEvery(4,1,2) #odd field first (TFF)

	v=converttoyuy2(v) #corrects YV12 artifacts
	v=weave(v) #re-interlace

	return(v)
}

# Converts 1920x1080i to 720x480p at 30 fps
function v720x480p30(v)
{
	v=bob(v)
	v=AssumeFrameBased(v)

	v=v.BilinearResize(720,480)
	v=SelectEven(v)

	return(v)
}