Video Recording to laptop...Underwater camera

[gravinus]

I have purchased an underwater camera for ice fishing that I want to run to my laptop. I can't find any software to do what I need. I would like something the pre-records around 20 seconds of video so if I see something interesting I can hit record and save like 20 seconds of video prior to me hitting record.


Is there anything out there that will do this?

Thanks for reading and any help is GREATLY APPRECIATED!!

Ben

[Safesurfer]

If you can find an old copy, Adobe DV Rack 2 (used to be a Serious Magic product) might do what you need. Unfortunately it is now called Adobe OnLocation and is only available as part of the Adobe Premiere Pro CS4 suite. Maybe some kind of video surveillance software would work as well, might be worth Googling around.

[olyteddy]

My Hauppauge PVR and its WinTV softwrae has a 'Pause' mode that does something like that. It records an hour long buffer that can be treated like any other video file. Perhaps some sort of home theater software could do what you want.

[edDV]

Most PVR software allows a continuos cache of input to temporary storage (user defined) that gets flushed after a specified delay.

Idea is you can pause and review past video without permanent storage.

Not all do this from external input. Your turn.

[Safesurfer]

Another thought, the free Enosoft DV Processor has a Time Delay function, but I'm not sure exactly what it does - perhaps you can ask Johnny Malaria at Enosoft it it will work as a pre-capture buffer.

[gravinus]

Thanks everyone for the good info! I will play with the Enosoft program to see if I can make that work....


Ben

[JohnnyMalaria]

It doesn't have a precapture buffer per se but you could achieve the same result in a slightly different way. You can daisychain multiple copies of the software together and use one to monitor the live image and feed a delayed version of it to other copy (say 5 seconds). When you see something you want to record on the live feed, you start capturing on the delayed feed - you'll end up capturing video that starts about 5 seconds before the point you decide you want to record.

It's actually a lot simpler to do than describe and, if you do it a lot, you can create a simple VBScript to set it all up automatically.

If I get a chance, I'll try to pull something together but the essence is this:

First copy of DV processor:

Input = camcorder
Time delay = 5 second (or whatever you'd like)
Output = Enosoft Virtual DV Renderer

Second copy:

Input = Enosoft Virtual DV Source
Output = DV AVI file

[gravinus]

John, thanks for the info! That sounds like it might be the ticket. If you have any other hints on what I need to do to make it function I would love to hear them!!!


Thanks Again, I really appreciate everyone's help!

Ben

[JohnnyMalaria]

Here's a VBScript that will do the job. The script file is attached.

This works by using two DV processors and described in the previous reply. Note, position the two processors on the screen in such a way that you can see the prompts from this script otherwise you won't see them (though you will see something in the taskbar).

Define a few variables

Dim AppSrc, AppDst, Delay, DeviceFound, Res

Create two Enosoft DV Processors - one for getting the video from the camcorder (the source) and one for saving the file (the destination)

Set AppSrc = CreateObject("EnoDVProcessor.EnoDV2DVApplication.1")
Set AppDst = CreateObject("EnoDVProcessor.EnoDV2DVApplication.1")

Make both of them visible (they are invisible by default)

AppSrc.Visible = True
AppDst.Visible = True

Name them with helpful values to make it easier to distinguish them

AppSrc.Caption = "From Camera"
AppDst.Caption = "To Capture File"

Set your desired delay in seconds (effectively, the precapture buffer)

Delay = 5

Enable the time delay from the source. The input window will show the live video, the output will show the delayed video. You will look at the input window to decide your starts and stops. A more sophisticated version could display the live video in a larger window.

AppSrc.TimeDelayAndTimeLapseEnable = True
AppSrc.TimeDelayEnable = True
AppSrc.TimeDelay = Delay

Look for the camcorder by enumerating all the "devices" (all the items listed in the input drop-down list). We are looking for an external (i.e., connected via FireWire) device.

DeviceFound = False
For C = 0 To AppSrc.InputDeviceCount - 1
	If AppSrc.GetInputDeviceExternal(C) Then
                AppSrc.CurrentInputDevice = AppSrc.GetInputDeviceName(C)
		DeviceFound = True
        End If
Next

If no device was found give the user the option to quit or to select an AVI file (not recommended since VBScript is rather simple and creates weird threading issues)

If Not DeviceFound Then
	Res = MsgBox ("No DV source found.  Click OK to close or Cancel to use file...", vbOKCancel, "Delay Test")
	If Res = vbOK Then
		AppSrc.Quit
		AppDst.Quit
		WScript.Quit 0
	End If

This ensures the destination processor is on top and visible (otherwise the source covers it up)

	AppDst.Visible = False
	AppSrc.CurrentInputDevice = "DV File..."
	AppDst.Visible = True
End If

We use Virtual DV to daisychain the two processors so set up the output of the source processor and the input of the destination processor accordingly. Start the source running, too.

AppSrc.CurrentOutputDevice = "Enosoft Virtual DV Renderer"
AppSrc.RunProcessor()

AppDst.CurrentInputDevice = "Enosoft Virtual DV Source"

We can make the processor generate unique filenames with time/date.

AppDst.EmbeddedEnable = True
AppDst.EmbeddedSceneDetectionEnable = True

Ask for the filename (the time/date will be appended to this). If you need Type-2, change this to "Type-2 DV AVI File...". For raw DV files, change it to "Raw DV File..."

AppDst.CurrentOutputDevice = "Type-1 DV AVI File..."

Enter a loop that allows you to start and stop capture, creating a new file each time. Provide an option to finish.

Res = vbOK

Do
	MsgBox "Click OK to start capturing...", vbOKOnly, "Delayed Capture"
	AppDst.RunProcessor()
	Res = MsgBox ("Click OK to stop capturing or Cancel to finish...", vbOKCancel, "Delayed Capture")
	AppDst.PauseProcessor()
Loop Until Res = vbCancel

Stop the capture (this ensures the last file gets finalized) then close both processors

AppDst.StopProcessor()
AppSrc.Quit
AppDst.Quit

delaycapture.vbs

[gravinus]

Hey John, thanks for putting this together..... Now I have one really stupid newbie question for everyone......... What do I do with this VBScript file to make this program work?

Thanks again to everyone for all the help... I'll post some interesting underwater fish videos when I get some captured!!

Ben

[JohnnyMalaria]

Hi Ben,

I suppose that small detail would help. Just save the file to a suitable location (e.g., your desktop) and then double-click on it. It should have a big blue S icon.

I'd be interested in seeing the video - most of my video is shot underwater, too.

John.

[gravinus]

Hey John, I haven't had a chance to mess with the program yet. I will be testing it out tonight. With this new one you posted do I still open 2 copies and set them up according to your earlier post? I should get some pretty cool videos, last week I saw a huge northern with a spinner stuck in its lip.

Thanks, Ben

[JohnnyMalaria]

No, just double-click on the file. It takes care of everything. You'll see two processors launch. You'll have to drag them around the screen so that you can see the prompts that the script shows (dead center of the screen). Assuming you have the camcorder hooked up, you'll go straight to the point where you will see a prompt asking you to specify the capture filename (it will append the date/time to this). Then you'll see a prompt asking you to click OK to start capturing. Once started, another prompt appears asking you to click OK to stop or Cancel to end everything. It keeps looping this start/stop cycle until you choose Cancel.

To change the delay, open the script file in Notepad, edit the line "Delay = 5" and save it.

John.