Help with Mkvmerge

[TeddyBear10]

Hi all,

I have more than 50 mkvs that I would like to mux with subtitles. It will take a lot of time if I have to do it one by one. I read somewhere that you can do this by creating a batch file. Unfortunately, I have no idea how to do it. I hope somebody can help me. Thank you.

[Baldrick]

How are your video and subtitles files named? It will be easy if they are named same like video.mkv and video.srt.

[TeddyBear10]

How are your video and subtitles files named? It will be easy if they are named same like video.mkv and video.srt.

They are name like this:

Avatar (2009).mkv
Avatar (2009)_track02.srt


Thanks for helping

[Baldrick]

Always with _track02.srt?

[Baldrick]

Mkvmerge batch code:

FOR %%f IN (*.mkv) DO (
mkvmerge -o c:\newfolder\%%~nf-new.mkv %%~nf.mkv %%~nf_track02.srt
)

See https://forum.videohelp.com/threads/353334-%5BHelp%5D-Remux-multiple-mkv-with-ssa?p=221...=1#post2219832 for full details.

[TeddyBear10]

Mkvmerge batch code:

FOR %%f IN (*.mkv) DO (
mkvmerge -o c:\newfolder\%%~nf-new.mkv %%~nf.mkv %%~nf_track02.srt
)

See https://forum.videohelp.com/threads/353334-%5BHelp%5D-Remux-multiple-mkv-with-ssa?p=221...=1#post2219832 for full details.

Do I need to change anything on your script or just copy paste & follow your instruction here
"Put the test.bat and mkvmerge.exe in same folder as your mkv files.
Create a new folder for you new mkv files, the c:\newfolder in this example. It should NOT be same as your current mkv/ssa files.
Run the test.bat. You can try with a few mkv/ssa files first."


To answer your question yes all of the subs (srt's) always have "_track02" at the end.


Question for you.

1. The script you provided will it also remove all the subtitles in the movie?

Basically what I would like to do is to remux all mkvs with the new subtitle (with "_track02") but remove all the original subs from the mkv.


2. Will it leave everything by default for the video,audio,chapters and tags?



Im totally noob at this I appreciate your help.

[Baldrick]

Just copy everything and try with ONE mkv first.

I don't think it will remove any subs. I don't know how to do that easy using the batch batch.

You can also read https://forum.videohelp.com/threads/356314-How-to-batch-convert-multiplex-any-files-with-ffmpeg (how batch script works with ffmpeg but you use mkvmerge instead)

[TeddyBear10]

I will check on it once I get home and will update here how it works

[ndjamena]

Add -S (note the capital S) between the output file name and the source MKV name to remove the subtitles from the remux.

FOR %%y IN (*.mkv) DO (
	mkvmerge -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" "%%~dpny_track02.srt"
)

[roma_turok]

To answer your question yes all of the subs (srt's) always have "_track02" at the end.

Or simple remove in SRT name _track02 with batch rename program like ReNamer
drag all SRT files to program, add Remove _track02 and click rename
Players like VLC or XBMC always play video with SRT subtitle first, if name of video and subtitle its same
even if video contain subtitles

[ndjamena]

To answer your question yes all of the subs (srt's) always have "_track02" at the end.

Or simple remove in SRT name _track02 with batch rename program like ReNamer
drag all SRT files to program, add Remove _track02 and click rename
Players like VLC or XBMC always play video with SRT subtitle first, if name of video and subtitle its same
even if video contain subtitles

You don't actually need to remove the _track02 for that to work, they look for anything that STARTS with the original file name, otherwise you wouldn't be able to have multiple srt files for a single video file.

[TeddyBear10]

[QUOTE=Baldrick;2360814]Mkvmerge batch code:

FOR %%f IN (*.mkv) DO (
mkvmerge -o c:\newfolder\%%~nf-new.mkv %%~nf.mkv %%~nf_track02.srt
)

Tried it. Didn't work.

I created a new folder put one mkv and sub. Then copy pasted the code above onto notepad save as *all files* name mux.bat. Also, I copy the mkvmerge icon into the same folder. When I click the .bat file cmd opens for a second then disappear.

Anything I did wrong?

[TeddyBear10]

Add -S (note the capital S) between the output file name and the source MKV name to remove the subtitles from the remux.

FOR %%y IN (*.mkv) DO (
	mkvmerge -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" "%%~dpny_track02.srt"
)

Thanks for chiming in. Tried this too with the same result above.

[ndjamena]

Then you're doing something wrong. What, if any, error messages are being thrown at you? (open a command prompt, CD /D to the directory, then type in the name of the .bat and the window will stay open once the bat has run).

-Edit- Oh, you need the actual MKVMerge.exe somewhere the batch can find it, not just a shortcut. The exe is in the Program Files directory (in windows) MKVToolNix, you can move the exe, add the full path name to the bat or add the full MKVTopolNix directory name to the PATH system variable.

[newpball]

Mkvmerge batch code:

FOR %%f IN (*.mkv) DO (
mkvmerge -o c:\newfolder\%%~nf-new.mkv %%~nf.mkv %%~nf_track02.srt
)

Tried it. Didn't work.

I created a new folder put one mkv and sub. Then copy pasted the code above onto notepad save as *all files* name mux.bat. Also, I copy the mkvmerge icon into the same folder. When I click the .bat file cmd opens for a second then disappear.

Anything I did wrong?

Did you run this from a cmd window?

[TeddyBear10]

Update--- after hours of playing with the batch it finally work. I put the mkvmerge path instead of just "mkvmerge". The original subs were gone.yey. I also added "--language 0:eng" to set the language of sub to english based on what I read from here https://www.bunkus.org/videotools/mkvtoolnix/doc/mkvmerge.html
This is what I came up with.

FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt"
)

Does it look alright? Will it set all the settings for the video,audio,chapters and tags by default like the original mkv?I just dont want to start ripping dvd's again if I messed up
and is there anything I can add to get like a log in text file from the batch?

[ndjamena]

FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt">"%%~dpny.log"
)

[roma_turok]

You don't actually need to remove the _track02 for that to work, they look for anything that STARTS with the original file name, otherwise you wouldn't be able to have multiple srt files for a single video file.

I know that
but if you have option remove this with single click, why not.

[aazerty]

Hi TeddyBear10 ,

> is there anything I can add to get like a log in text file from the batch?
YES .

@echo on
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt">"%%~dpny.log"
)
pause
:end

The CMD screen will stay open during the process .
!!! At the end , DON'T strike any key of the keyboard !!!
Right-click on that page => choose 'Select all' => Click on the 'ENTER' key .

Open a text editor => paste the clipboard .
Here , you have what you have selected .

The properties of the CMD file can be nodified , when a batch file is open ( for example ) .
Colors , number of lines , Height , width , etc.

Regards .

[ndjamena]

Um, you probably should have copy/pasted an earlier batch, mine already outputs to a log.

>"%%~dpny.log"

I could get it to output to the screen AND a log using a for /f loop...

FOR %%y IN (*.mkv) DO (
	echo.>"%%~dpny.log"
	for /f "tokens=* delims=" %%g in ('"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~ny-new.mkv" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt"') DO (
		echo %%g
		echo %%g>>"%%~dpny.log"
	)
)

[aazerty]

Hi ndjamena ,

Thanks for your's informations about log .
( I am a bit old , my mind is tired ) .

Regards .

[TeddyBear10]

FOR %%y IN (*.mkv) DO (
	echo.>"%%~dpny.log"
	for /f "tokens=* delims=" %%g in ('"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~ny-new.mkv" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt"') DO (
		echo %%g
		echo %%g>>"%%~dpny.log"
	)
)

for some reason this doesn't work for me. it only creates a blank log file no muxing took place. I also tried to run it from cmd but it didn't do anything.

@echo on
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt">"%%~dpny.log"
)
pause
:end

This one works. just one hiccup it created a log for every single mkv. This will be a little bit of work for me clicking every one of them instead of just one log file. But I guess I can find a simple program to scrape all the logs and put it in one text file.

[_Al_]

you can always add a single log to one LOG that holds all of them, echo or type perhaps can return wrong thing while calling from within parentheses so maybe it is a good idea to just call function that always add single log that complete log:

@echo on
break>all_logs.log
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt">"%%~dpny.log"
	call :print_log "%%~dpny.log"
        del "%%~dpny.log"
)
pause
:end

:print_log 
echo. >>all_logs.log
echo %~n1.LOG >>all_logs.log
echo --------------------------------- >>all_logs.log
type "%~1">>all_logs.log
goto :eof

[aazerty]

Hi TeddyBear10 ,

For example : you own 3 files .log in witch you have a text written .

--- Fichier_1.log
Fichier_1.mkv

--- Fichier_2.log
Fichier_2.mkv

--- Fichier_3.log
Fichier_3.mkv

If you create a batch file like below

@echo on
copy /b Fichier_1.log +Fichier_2.log +Fichier_3.log Groupement_1.log
rem OR
copy /b Fichier_*.log Groupement_2.log
pause
:fin

You'll get the same result for Groupement_1.log and Groupement_2.log
---
Fichier_1.mkvFichier_2.mkvFichier_3.mkv
---

Cheers .

[_Al_]

yes, copy is a nice example too, it can join txt files

[TeddyBear10]

@echo on
break>all_logs.log
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt">"%%~dpny.log"
	call :print_log "%%~dpny.log"
        del "%%~dpny.log"
)
pause
:end

:print_log 
echo. >>all_logs.log
echo %~n1.LOG >>all_logs.log
echo --------------------------------- >>all_logs.log
type "%~1">>all_logs.log
goto :eof

It works perfectly. Just one log for all the mkv's. Thank you everyone I really appreciate all your help. this will save me a lot of time!

[TeddyBear10]

I hate to bring this old thread back but I just need help to modify the code below to use it for another two different batch process.
Basically, I would like to do the the following seperately
(1) remux mkvs without the original subtitles in it (just keep the video & audio file)

(2) remux mkvs with two new subtitles with name ending in "_track02" & "_track03". Track02 should be labeled forced & track03 is default track and should be next to audio in order of tracks.

Example:
Movie\Avatar.mkv (this has two subtitles in it)
\Avatar_track02.srt
\Avatar_track03.srt

Order of tracks after remux
Video
Audio
Track03 (default)
Track02 (forced)

Thank you for helping.

@echo on
break>all_logs.log
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --language 0:eng "%%~dpny_track02.srt">"%%~dpny.log"
	call :print_log "%%~dpny.log"
        del "%%~dpny.log"
)
pause
:end

:print_log 
echo. >>all_logs.log
echo %~n1.LOG >>all_logs.log
echo --------------------------------- >>all_logs.log
type "%~1">>all_logs.log
goto :eof

[sneaker]

1.)

@echo on
break>all_logs.log
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy">"%%~dpny.log"
	call :print_log "%%~dpny.log"
        del "%%~dpny.log"
)
pause
:end

:print_log 
echo. >>all_logs.log
echo %~n1.LOG >>all_logs.log
echo --------------------------------- >>all_logs.log
type "%~1">>all_logs.log
goto :eof

2.)

@echo on
break>all_logs.log
FOR %%y IN (*.mkv) DO (
	"C:\Program Files (x86)\MKVToolNix\mkvmerge.exe" -o "%%~dpyremuxed\%%~nxy" -S "%%~fy" --default-track 0:1 --forced-track 0:0 "%%~dpny_track03.srt" --default-track 0:0 --forced-track 0:1 "%%~dpny_track02.srt">"%%~dpny.log"
	call :print_log "%%~dpny.log"
        del "%%~dpny.log"
)
pause
:end

:print_log 
echo. >>all_logs.log
echo %~n1.LOG >>all_logs.log
echo --------------------------------- >>all_logs.log
type "%~1">>all_logs.log
goto :eof

Try to learn:
https://mkvtoolnix.download/doc/mkvmerge.html
Maybe MKVBatch will interest you as well.