Imutube hd this script encode video to hd
use 1 pictures + 1 song...
but in now how i can make it on multi-pictures.
can any one give script multi-pictures (10 or 20 30..... pictures+ 1)
this script Imutube HD.
Code:
@echo off
color 0d

:check_avisynth
dir "%ProgramFiles%" | find /I /C "avisynth" > tmp
set /P str=<tmp && del tmp && cls
IF %ERRORLEVEL% NEQ 0 set str=0
if %str% GEQ 1 goto check_avisynth_end
dir "%ProgramFiles(x86)%" | find /I /C "avisynth" > tmp
set /P str=<tmp && del tmp && cls
if %str% GEQ 1 goto check_avisynth_end
echo Are you sure you have AviSynth installed? Avisynth is required
echo for the script to work properly. Get it at http://avisynth.org
echo.
echo You can press any key if you wish to continue,
echo but be warned that things might not work as they should =D
echo.
pause > NUL
:check_avisynth_end
cd /d %~dp0

:source_check
if NOT EXIST "%~f1" goto source_fail
if NOT EXIST "%~f2" goto source_fail
if /I [%~x1] == [.mp3] (set sourcea=1) else (if /I [%~x2] == [.mp3] set sourcea=2)
if /I [%~x1] == [.aac] (set sourcea=1) else (if /I [%~x2] == [.aac] set sourcea=2)
if /I [%~x1] == [.m4a] (set sourcea=1) else (if /I [%~x2] == [.m4a] set sourcea=2)
if /I [%~x1] == [.jpg] (set sourcev=1) else (if /I [%~x2] == [.jpg] set sourcev=2)
if /I [%~x1] == [.png] (set sourcev=1) else (if /I [%~x2] == [.png] set sourcev=2)
if /I [%~x1] == [.bmp] (set sourcev=1) else (if /I [%~x2] == [.bmp] set sourcev=2)
if [%sourcea%] == [] goto source_fail
if [%sourcev%] == [] goto source_fail
goto source_pass
:source_fail
cls
echo I didn't get the input files! Select both audio and picture
echo and then drag-n-drop it into the script file at the same time.
echo.
echo Supported input files:
echo  Photo: JPG/PNG/BMP
echo  Audio: MP3/AAC
echo.
echo.
pause
goto end
:source_pass
echo Working...
echo.

:variables
if [%sourcea%]==[1] ( set m1="%~n1" && set m2="%~n2" ) ELSE  ( set m1="%~n2" && set m2="%~n1" )
if [%sourcea%]==[1] ( set output="%~n1 (MicroHD).mkv" ) ELSE  ( set output="%~n2 (MicroHD).mkv" )
if [%sourcea%]==[1] ( set sourcea="%~f1" ) ELSE  ( set sourcea="%~f2" )
if [%sourcev%]==[1] ( set sourcev="%~f1" ) ELSE  ( set sourcev="%~f2" )

set m1=%m1: =%
set m1=%m1:-=%
set m1=%m1:_=%
set m1=%m1:.=%
set m1=%m1:&=%
set m1=%m1:(=%
set m1=%m1:)=%
set m1=%m1:"=%
set m1=%m1:'=%
set m2=%m2: =%
set m2=%m2:-=%
set m2=%m2:_=%
set m2=%m2:.=%
set m2=%m2:&=%
set m2=%m2:(=%
set m2=%m2:)=%
set m2=%m2:"=%
set m2=%m2:'=%
set m1=%m1:~0,24%
set m2=%m2:~0,24%
set m=immd-%m1%-%m2%

:resolution_check
tools\MediaInfo --Inform=Image;%%Width%%  %sourcev% > %m%
set /P width=<%m%&& del %m%
tools\MediaInfo --Inform=Image;%%Height%%  %sourcev% > %m%
set /P height=<%m%&& del %m%
set resolution=%width%x%height%
if %resolution%==1280x720 goto resolution_pass
if %resolution%==960x720 goto resolution_pass
cls
echo Your source picture is not 1280x720 (its %resolution%),
echo and thats not recommended. Youtube HD works best with 1280x720.
echo.
echo Enter "y" (or hit Enter) to resize to 1280x720 on the fly, or
echo enter "n" if you still insist on continuing without resizing...
echo.
set /p resize=Auto resize to 1280x720 [y]? 
IF %ERRORLEVEL% NEQ 0 set resize=y
if %resize%==n goto resolution_pass
set width=1280
set height=720
:resolution_pass

:make_avs
echo ImageSource(%sourcev%, end = 19800, fps=30).LanczosResize(%width%,%height%).ConvertToYV12() > %m%.avs

:variables_frames
tools\MediaInfo --Inform=General;%%Duration%% %sourcea% > %m%
set /p frames=<%m%&& del %m%
set /a frames=%frames% * 30 / 1000

:variables_keyint
set keyint=300

:variables_cats
set /a cats=%frames%/%keyint%

:encode_slice
tools\x264 --fps 30 --frames %keyint% --keyint %keyint% --qp 20 --8x8dct --me umh --threads auto --thread-input --progress --no-dct-decimate --no-psnr --no-ssim --output %m%.mp4 %m%.avs
del %m%.avs

:bad_avs
FOR /F %%A IN ("%m%.mp4") DO IF %%~zA EQU 0 goto bad_avs_error
goto bad_avs_end
:bad_avs_error
del %m%.mp4
cls
echo Error: Couldn't encode to x264.
echo.
echo Please try using only alpha-numeric (a-z, 0-9) characters in source filename. 
echo AVISynth has issues with some symbols and non-english characters.
echo.
pause
goto end
:bad_avs_end

set mp4=%m%.mp4
set bat=%m%.bat
if %cats% GEQ 100 goto box_script2
:box_script
set i=1
set /a x=%cats%
echo tools\box %mp4% ^^> %bat%
:loop
if %i%==%x% goto loop_end
echo -cat %mp4% ^^>> %bat%
set /a i=%i%+1
goto loop
:loop_end
echo -cat %mp4%>> %bat%
call %bat%
:box_script_end
del %bat%
goto mux

:box_script2
set i=1
set /a x=100
echo tools\box %mp4% ^^> %bat%
:loop2
if %i%==%x% goto loop_end2
echo -cat %mp4% ^^>> %bat%
set /a i=%i%+1
goto loop2
:loop_end2
echo -cat %mp4%>> %bat%
call %bat%
set /a cats=%cats%/100 + 1
:box_script3
set i=1
set /a x=%cats%-1
echo tools\box %mp4% ^^> %bat%
:loop3
if %i%==%x% goto loop_end3
echo -cat %mp4% ^^>> %bat%
set /a i=%i%+1
goto loop3
:loop_end3
echo -cat %mp4%>> %bat%
call %bat%
:box_script2_end
del %bat%
goto mux

:mux
tools\ffmpeg -i %sourcea% -acodec copy -i %m%.mp4 -vcodec copy %output% -shortest
del %m%.mp4

:end