Avisynth conversion of LD original capture

[ehbowen]

In honor of Star Wars Day 2024...

Okay, I've had a long layoff from AviSynth (and I was never really a guru...more of a recipe follower). But I have obtained a LaserDisc copy of the original Star Wars trilogy (before CGI and where Han Shoots First) and I'm wanting to adapt it so that it shows in optimal quality on my 16:9 TVs.

The LD was letterboxed for 4:3 TVs, and when played directly on mine shows up as both letterboxed AND pillarboxed...with something akin to a postage stamp of action in the middle. I made a good capture of the LD original to a lossless .avi using my All-In-Wonder setup. Now I'm wanting to reformat it to take advantage of the full width of a 16:9 screen, while at the same time preserving the subtitles which appear in the lower letterbox.

This is the script I'm using for a first cut:

AviSource("D:\StarWars\StarWars4LDPt2.avi")
ColorYUV(cont_Y=10)
Tweak(cont=1.05,sat=1.3,dither=true,coring=false)
Levels(18,1.0,255,16,255,dither=true,coring=false)

AssumeTFF()
ConvertToYV12(interlaced=true)

QTGMC(sharpness=0.6,border=true)

AddGrainC(1.5,1.5)
Crop(4,60,0,-10).AddBorders(2,4,2,6)    
Spline36Resize(Width,480)

Can someone make recommendations for improvement? After I get the lossless conversion to .avi format, I'm planning to convert to .mp4 and load it onto my home video server. Thanks!

[jagabo]

Nobody can make recommendations without seeing a sample.

[ehbowen]

Fair enough.

Here's a clip of the original LD raw capture (StarWars4LDclip-org.avi) and a clip after being resized and run through QTGMC with the script in my original post (StarWars4LDclip-proc.avi).

[jagabo]

QTGMC is not appropriate for film based sources. You want to use TFM().TDecimate() instead. That will get you back to the original film frames. The levels and cropping are hard to say for sure, but try something like this:

LWLibavVideoSource("StarWars4LDclip-org.avi") 
TFM()
TDecimate()
Spline36Resize(640, 480)
Crop(0,102,0,-10)
ColorYUV(gain_y=-15, off_y=-4, cont_u=100, cont_v=100)
ConvertToYV12()
MergeChroma(SMDegrain(thsad=200, tr=3, PreFilter=4), SMDegrain(thsad=1000, tr=3, PreFilter=4).aWarpSharp(depth=10))
ChromaShiftSP(x=-1, y=2)
aWarpSharp2(depth=5)
Sharpen(0.5, 0.0)

[ehbowen]

All right, I'm trying your suggested script but I'm having plugin problems. It's calling for a function called KNLMeansCL which does not exist. I found the plugin online and attempted to install it. When I use the "Load Plugin" command it tells me that this .dll cannot be used as an AviSynth plugin; when I try placing it in the regular plugins directory I get a "System Access Violation" message. I did install the redistributable Visual C++ for Visual Studio 2015 which is listed as a dependency. Still no luck.

Anyhow, right now I think I'm going to spend about two hours watching the version I converted with my first script. I'd like to see how it compares with the TFM version, but it looks adequately watchable as is.

Thanks for the help so far.

[Alwyn]

I tried and initially got the same error re KNLMeansCL.

Assuming your have Visual C++ dist installed...

I went here:

https://github.com/pinterf/KNLMeansCL/releases

In the first section, click on "Assets 3" and the KNL...7Z file will be shown. Download it, unzip it with Right-Click "Extract All..."

Open up the "x64" folder folder that is created (amoung others) and the KNLMeansCL.DLL file will be visible.

Copy and paste that file into your AviSynth+ Plugins64+ folder and you should be good to go.

[lollo]

On my LD captures, I generally only apply a basic filtering:

video_org=AviSource("StarWars4LDclip-org.avi")

# IVTC
video_org_ivtc=video_org.AssumeTFF().TFM(order=1, mode=0, PP=0, slow=2, field=1).TDecimate()

### convert to YV16
deinterlaced_yv16=video_org_ivtc.convertToYV16()
### denoising
denoised_yv16=deinterlaced_yv16.TemporalDegrain2(degrainTR=3)
### convert to YUY2
denoised=denoised_yv16.convertToYUY2()

### convert to YV12
denoised_yv12=denoised_yv16.convertToYV12()
### sharpening
sharpened_yv12=denoised_yv12.LSFmod(defaults="slow")
### convert to YUY2 with chroma from YUY2 color space
restored=sharpened_yv12.convertToYUY2().MergeChroma(denoised)

return(restored)

comparison side by side:


comparison with slider:
https://imgsli.com/MjYxNjEw

restored video:
rest.avi

[rgr]

### convert to YV12
denoised_yv12=denoised_yv16.convertToYV12()
### sharpening
sharpened_yv12=denoised_yv12.LSFmod(defaults="slow ")
### convert to YUY2 with chroma from YUY2 color space
restored=sharpened_yv12.convertToYUY2().MergeChrom a(denoised)

You can use LSFplus -- it has no restrictions like LSFmod.

[lollo]

You can use LSFplus -- it has no restrictions like LSFmod.

Yes!