Badly deinterlaced video

[themaster1]

I usually stay away from that kind of footage but here i go.
The file is 1080p but was most likely 480i originally

sample here:
https://mega.nz/file/81IRBS4a#nGkvuV3h99x4MbAyDv6SYFtq2rQ3RWegGMcN3tMN_To
.
avisynth script welcomed (or better i'm open)

Thanks for your help

edit:
Well so far i came up with this:

LWLibavVideoSource(source="video.MOV")
SeparateFields()
e=SelectEven().Yadif(mode=0, order=-1, planar=false, opt=-1)
o=SelectOdd().Yadif(mode=0, order=-1, planar=false, opt=-1)
Interleave(e,o)
Weave()
return last.spline36resize(720,480) # (the resizing works best at the end, not before it seems)

Johnmeyer has coded a script specifically for this it seems, but i can't make it work right

Source: https://forum.doom9.org/showthread.php?p=1685187#post1685187

[johnmeyer]

I don't see any evidence of the "resize interlaced video without first deinterlacing" problems that I dealt with in that thread. Actually, I don't see too much wrong with your clip, other than the total lack of any detail.

[jagabo]

Uhg, that's some ugly source. Here's what I came up with:

###################################################
#
# build a mask of areas where there are 
# alternating horizontal lines
#
##################################################

function AltHzLineMask(clip v)
{
    Subtract(v, v.blur(0.0, 1.0).Sharpen(0.0, 0.6))
    GeneralConvolution(0, "
        0  8  8  8  0
       -0 -8 -8 -8 -0 
        0  8  8  8  0
       -0 -8 -8 -8 -0
        0  8  8  8  0", chroma=false, alpha=false)
    mt_lut("x 125 - abs")
    mt_binarize(6) # threshold, adjust to source
    mt_inpand()
    mt_expand()
    mt_expand(chroma="-128")
}

##################################################


LSmashVideoSource("2Pac_Snoop-sample.mp4") 

src = last


# build a mask of areas where there is combing
ConvertToYV24() # convert to YV24 so we can specify an odd height
Spline36Resize(width,431) # found experimentally
AltHzLineMask()
mask = Blur(1.0).BilinearResize(src.width, src.height).ConvertToYV12()


# blur the comb artifacts by downscaling, then upscaling
src
Spline36Resize(width, 240)
Spline36Resize(width,1080)

# overlay the blurred image only where there are comb artifacts
Overlay(src, last, mask=mask)

# show before, after, mask
#Interleave(src, last, mask)

You'll get blending where there used to be comb artifacts. The video is too far gone for something like FixBlendIVTC() to repair it after this.

[themaster1]

I'm tryin' your script with avisynth 2.6 MT jagabo: error "general convolution does not have a named argument chroma"

[jagabo]

I'm using AviSynth+. 2,6 GeneralConvolusion only works with RGB32 Remove the chroma and alpha arguments. And ConvertToRGB32() before calling it, then ConvertToYV24() after.

function AltHzLineMask(clip v)
{
    Subtract(v, v.blur(0.0, 1.0).Sharpen(0.0, 0.6))
    ConvertToRGB32()
    GeneralConvolution(0, "
        0  8  8  8  0
       -0 -8 -8 -8 -0 
        0  8  8  8  0
       -0 -8 -8 -8 -0
        0  8  8  8  0")
    ConvertToYV24()
    mt_lut("x 125 - abs")
    mt_binarize(6) # threshold, adjust to source
    mt_inpand()
    mt_expand()
    mt_expand(chroma="-128")
}

[themaster1]

thanks jagabo, i like your script, that plus qtgmc("slower",inputtype=1) right after works best imo. I don't think i can expect much better i'll stop bangin my head for now.