batch to calculate duration of all video files in a directory?

[marcorocchini]

H* ***s

please I wonder if is possible to do a batch that calculate the total duration of a variable number of video files that are in a folder

[sneaker]

http://skwire.dcmembers.com/fp/?page=playtime

[marcorocchini]

thanks *** but seems don't recognize .MXF files, and possibly I need to put the value in a enviroment variable.

Maybe with ffprobe? but I'm not able

[jagabo]

Something like this:

@echo off
SET Mediainfo="G:\Program Files\MediainfoCLI\Mediainfo.exe"
set /A total_milliseconds=0
for %%F in (*.mxf) do (call :RUNTIME1 "%%F")
echo.
echo Total milliseconds = %total_milliseconds%
echo.
pause
exit 0

:RUNTIME1

set /A duration_milliseconds=0
%Mediainfo% --Inform=Video;%%Duration%% %1 > temp.tmp
set /p duration_milliseconds=<temp.tmp
echo %1 : %duration_milliseconds% milliseconds
set /A total_milliseconds=%total_milliseconds%+%duration_milliseconds%
EXIT /B

[JVRaines]

Here's a way to do it with ExifTool, assuming exiftool.exe is in your search path. totSecs will give you total seconds and totalDuration will give total formatted time.

@echo off
set /p targDir=Target directory: 
cd /d %targDir%
set totSecs=0
for %%F in (*.*) do (
	for /f "tokens=1-3 delims=: usebackq" %%X in (`exiftool -duration -s3 "%%F"`) do (
		set /a "totSecs += %%X*3600 + (1%%Y %% 100)*60 + (1%%Z %% 100)"
	)
)
set /a hours=%totSecs%/3600
set /a mins=(%totSecs% %% 3600)/60
set /a secs=%totSecs% %% 60
set totalDuration=%hours%:%mins%:%secs%

[marcorocchini]

********************************

[Attachment 42376 - Click to enlarge]