using avisynth to make part of a video slow motion

[pooksahib]

Hi. With the help of this forum I've become quite good at using avisynth to correct and convert DVDs. The next skill I want to get to grips with is slow motion. This is the script I'm working on:

global MeGUI_darx = 4
global MeGUI_dary = 3
LoadPlugin("E:\MeGUI\tools\avisynth_plugin\NicAudio.dll")
LoadPlugin("E:\MeGUI\tools\dgindex\DGDecode.dll")
a=DGDecode_mpeg2source("E:\testvid.d2v")
b=NicAC3Source("E:\testvid.ac3")
audiodub(a,b)
QTGMC()
trim(57,8180)++trim(8278,14740)++trim(12862,12990) ++trim(12862,12990)++trim(12862,12990)

I only wish the final scene (12862-12990) to be slomo. Audio synch is not an issue, I'll be overdubbing some music later. Can anyone suggest how I can do this? I found this post by jagabo:
https://forum.videohelp.com/threads/335908-How-can-I-get-the-smoothest-slow-motion-out-...=1#post2085931
which suggests that SmoothFPS is what I need but I just couldn't fathom how to incorporate his script into mine.

Supplementary question: the last scene is repeated twice. Can I script it a bit more tidily than simply saying ++trim(12862,12990)++trim(12862,12990)++trim(12862 ,12990)?

My thanks to anyone able to assist.

[jagabo]

If you want to use SmoothFPS2() from that post:

function SmoothFPS2(clip source, int num, int den) {
super = MSuper(source, pel=2, hpad=0, vpad=0, rfilter=4)
backward_1 = MAnalyse(super, chroma=false, isb=true, blksize=16, searchparam=3, plevel=0, search=3, badrange=(-24))
forward_1 = MAnalyse(super, chroma=false, isb=false, blksize=16, searchparam=3, plevel=0, search=3, badrange=(-24))
backward_2 = MRecalculate(super, chroma=false, backward_1, blksize=8, searchparam=1, search=3)
forward_2 = MRecalculate(super, chroma=false, forward_1, blksize=8, searchparam=1, search=3)
backward_3 = MRecalculate(super, chroma=false, backward_2, blksize=4, searchparam=0, search=3)
forward_3 = MRecalculate(super, chroma=false, forward_2, blksize=4, searchparam=0, search=3)
MBlockFps(source, super, backward_3, forward_3, num, den, mode=0)
} 

global MeGUI_darx = 4
global MeGUI_dary = 3
LoadPlugin("E:\MeGUI\tools\avisynth_plugin\NicAudio.dll")
LoadPlugin("E:\MeGUI\tools\dgindex\DGDecode.dll")
a=DGDecode_mpeg2source("E:\testvid.d2v")
b=NicAC3Source("E:\testvid.ac3")
audiodub(a,b)
QTGMC()
slow = trim(12862,12990).SmoothFPS2((int(framerate*4), 1).AssumeFPS(framerate) # slow to 1/4 speed
trim(57,8180)++trim(8278,14740)++trim(12862,12990)++trim(12862,12990)++slow

Change the "4" in the SmoothFPS2 arguments to set the speed you want. Note that motion interpolation like this doesn't work well with some types of video. Especially cartoons.

There are many other variations of this. Interframe() might work a little better.

[pippas]

You might find the script included in THIS PAGE useful - especially if you want to include any 'ease in' and 'ease out' timings to your slo-mo selection?...

[pooksahib]

Many thanks, jagabo and pippas. I'll look into pippas' suggestion later but, for now, jagabo's script did just fine (despite there being a superfluous '(' in the penultimate line!).

Thanks again folks.

[jagabo]

Ah yes, I lost count. There should only be one open parenthesis after SmoothFPS2, not two.