AVCHD 50p to DVD

[multitech]

Hello again dear forum coleagues. I have conversion problem and lok for some help from you. So I bought a Panasonic GH4 and want to record movies in AVCHD 50p format(or MOV 50p) but my clients want to deliver the footage in DVD format. The problem is that the image is jerky. Tried a lot of programes for this with no luck. I am asking you for a solution of this problem or maybe a script for avisynth to try. Thank you.

[djnice]

Hello,

The TMPGEnc Authoring Works producing interlaced PAL DVD from 50p AVCHD with fine movement, try it.

[multitech]

I have TMPGenc Authoring Works 4 but the result is horrible. Tried even with TMPGemc 4 xpress. no way.

[djnice]

Horrible? What does it mean?
If you want fine movement, the resulting DVD needs to be interlaced (25i).
With 25p, the picture is sharper, but the movement is jerky.

[multitech]

Of course I am looking for fine movement. In TMPGenc Authoring Works 4 tried TFF and BFF that is 25i and the movement is jerky.

[djnice]

Please provide a sample 50p AVCHD file, I will look at.

[manono]

I am asking you for a solution of this problem or maybe a script for avisynth to try. Thank you.

LanczosResize(720,576)###(if for PAL) or your favorite resizer
AssumeTFF()
SeparateFields()
SelectEvery(4,0,3)
Weave()

That will interlace it to 25 interlaced frames per second (25i) and should keep the fluidity of movement. Encode as interlaced.

[_Al_]

I cannot help it, IResize from Gavino/IanB gives the best results (50p HD to interlace DVD), also color change is needed from rec.709 to rec.601

# IResize by Gavino and IanB and mod by A.SONY to use Custom resizer and Extra resizer parameters may be passed via res_params. like this IResize(240,480,res_params=",src_left=5")
function IResize(clip c, int NewWidth, int NewHeight, string "resifilter", string "res_params") {
  resifilter   = default ( resifilter,         "Spline36resize" )
  res_params = default(res_params, "")
  c
  SeparateFields() 
  Shift = (GetParity() ? -0.25 : 0.25) * (Height()/Float(NewHeight/2)-1.0)
  v2=last
  SelectEven(v2)
  E  = Eval(resifilter + "(NewWidth, NewHeight/2, src_top=Shift" + res_params + ")")
  Ec = Eval(resifilter + "(NewWidth, NewHeight/2, src_top=2*Shift" + res_params + ")")
  SelectOdd(v2)
  O  = Eval(resifilter + "(NewWidth, NewHeight/2, src_top=-Shift" + res_params + ")")
  Oc = Eval(resifilter + "(NewWidth, NewHeight/2, src_top=-2*shift" + res_params + ")")
  Interleave(E, O)
  IsYV12() ? MergeChroma(Interleave(Ec, Oc)) : Last
  Weave()
}

IResize(720,576)
LoadPlugin("ColorMatrix.dll")
ColorMatrix(mode="Rec.709->Rec.601",clamp=0)
AssumeTFF().SeparateFields().SelectEvery(4, 0, 3).Weave()

or just put that IResize function in some avsi file and make script more readable:

Import("IResize.avsi")
IResize(720,576)
LoadPlugin("ColorMatrix.dll")
ColorMatrix(mode="Rec.709->Rec.601",clamp=0)
AssumeTFF().SeparateFields().SelectEvery(4, 0, 3).Weave()

[manono]

Oh, right, the Colormatrix change. Thanks.

[multitech]

Sorry for late. It works but do not recognize "clamp=0" deleted it and it works

[multitech]

Sample 50p AVCHD file

[manono]

It works but do not recognize "clamp=0" deleted it and it works

It's a good idea not to clamp. You have an older version where it's:

Clamp=False (I think).

Or update to the more recent version:

http://avisynth.nl/index.php/ColorMatrix#Chroma_correction

Maybe this will be for future reference since you seem happy with your result.

[_Al_]

Using your 50p 1920x1080 sample,
as a pretty common workflow ,I loaded clip into videoeditor (Sony Vegas), where footage could be edited, then export thru frame server as uncompressed avi, using different avisynth scripts, then using HcEncoder, then Muxman to mux VIDEO_TS, I got this:
IResize:

AviSource("C:\Untitled.avi")   
Import("IResize.avsi")
ConvertToYV12(matrix="PC.709")  
IResize(720,576)
LoadPlugin("ColorMatrix.dll")
ColorMatrix(mode="Rec.709->Rec.601",clamp=0)
AssumeTFF().SeparateFields().SelectEvery(4, 0, 3).Weave()

IResize with vertical blur 1.0 (low pass filter):

AviSource("C:\Untitled.avi")   
ConvertToYV12(matrix="PC.709")  
Import("IResize.avsi")
IResize(720,576)
Blur(0,1.0)
LoadPlugin("ColorMatrix.dll")
ColorMatrix(mode="Rec.709->Rec.601",clamp=0)
AssumeTFF().SeparateFields().SelectEvery(4, 0, 3).Weave()

Spline36Resize and vertical blur 1.0:

AviSource("C:\Untitled.avi")   
ConvertToYV12(matrix="PC.709")  
Spline36Resize(720,576)
Blur(0,1.0)
LoadPlugin("ColorMatrix.dll")
ColorMatrix(mode="Rec.709->Rec.601",clamp=0)
AssumeTFF().SeparateFields().SelectEvery(4, 0, 3).Weave()

basically IResize or low pass filter has to be used to prevent flicker (footage not usable), IResize is holding up quite well without that vertical blur as well