VideoHelp Forum

Our website is made possible by displaying online advertisements to our visitors. Consider supporting us by disable your adblocker or Try ConvertXtoDVD and convert all your movies to DVD. Free trial ! :)
+ Reply to Thread
Page 2 of 2
FirstFirst 1 2
Results 31 to 45 of 45
Thread
  1. Member
    Join Date
    Jan 2014
    Location
    iikingli
    Search Comp PM
    That was me trying a different folder structure... I used the default as well... for x64 system "programs (x86)...." same issue. I tried it on a win 8 , win 7, and server 2008 box all with Default MkVtoolnix locations and no luck .
    Quote Quote  
  2. Member fryk's Avatar
    Join Date
    Oct 2012
    Location
    Europe
    Search PM
    More information is needed about the source folder and files.
    Quote Quote  
  3. Member
    Join Date
    Jan 2014
    Location
    iikingli
    Search Comp PM
    mkvtoolnix location : C:\Program Files (x86)\MKVToolNix

    Start folder : "StartFolder=W:\Movies" "movies under here are .MKV withing all in their own subfolder

    Variables Command Set output:

    ALLUSERSPROFILE=C:\ProgramData
    APPDATA=C:\Users\Dave\AppData\Roaming
    asl.log=Destination=file
    CommonProgramFiles=C:\Program Files\Common Files
    CommonProgramFiles(x86)=C:\Program Files (x86)\Common Files
    CommonProgramW6432=C:\Program Files\Common Files
    COMPUTERNAME=OFFICE
    ComSpec=C:\WINDOWS\system32\cmd.exe
    FP_NO_HOST_CHECK=NO
    HOMEDRIVE=C:
    HOMEPATH=\Users\Dave
    JAVA_PLUGIN_WEBCONTROL_ENABLE=1
    LOCALAPPDATA=C:\Users\Dave\AppData\Local
    LOGONSERVER=\\MicrosoftAccount
    NUMBER_OF_PROCESSORS=8
    OPENSSL_CONF=C:\OpenSSL-Win32\bin\openssl.cfg
    OS=Windows_NT
    Path=C:\Program Files (x86)\Intel\iCLS Client\;C:\Program Files\Intel\iCLS Clie
    t\;C:\Program Files (x86)\NVIDIA Corporation\PhysX\Common;C:\WINDOWS\system32;C
    \WINDOWS;C:\WINDOWS\System32\Wbem;C:\WINDOWS\Syste m32\WindowsPowerShell\v1.0\;C
    \Program Files\Intel\Intel(R) Management Engine Components\DAL;C:\Program Files
    Intel\Intel(R) Management Engine Components\IPT;C:\Program Files (x86)\Intel\In
    el(R) Management Engine Components\DAL;C:\Program Files (x86)\Intel\Intel(R) Ma
    agement Engine Components\IPT
    PATHEXT=.COM;.EXE;.BAT;.CMD;.VBS;.VBE;.JS;.JSE;.WS F;.WSH;.MSC
    PROCESSOR_ARCHITECTURE=AMD64
    PROCESSOR_IDENTIFIER=Intel64 Family 6 Model 58 Stepping 9, GenuineIntel
    PROCESSOR_LEVEL=6
    PROCESSOR_REVISION=3a09
    ProgramData=C:\ProgramData
    ProgramFiles=C:\Program Files
    ProgramFiles(x86)=C:\Program Files (x86)
    ProgramW6432=C:\Program Files
    PROMPT=$P$G
    PSModulePath=C:\WINDOWS\system32\WindowsPowerShell \v1.0\Modules\
    PUBLIC=C:\Users\Public
    SESSIONNAME=Console
    SystemDrive=C:
    SystemRoot=C:\WINDOWS
    TEMP=C:\Users\Dave\AppData\Local\Temp
    TMP=C:\Users\Dave\AppData\Local\Temp
    USERDOMAIN=OFFICE
    USERDOMAIN_ROAMINGPROFILE=OFFICE
    USERNAME=Dave
    USERPROFILE=C:\Users\Dave
    windir=C:\WINDOWS
    Quote Quote  
  4. Member
    Join Date
    Jan 2014
    Location
    iikingli
    Search Comp PM
    Aslo no matter where i set the folder to scan from even with no sub-folders it gets the same issue.
    Quote Quote  
  5. Member
    Join Date
    Jan 2014
    Location
    iikingli
    Search Comp PM
    Originally Posted by fryk View Post
    More information is needed about the source folder and files.
    I figured it out will send you a direct PM
    Quote Quote  
  6. Member
    Join Date
    Feb 2013
    Location
    Chattanooga, TN
    Search Comp PM
    I made a video of myself changing the default audio/subtitle track using a batch file. The same tactic can be used to remove the track.

    https://www.youtube.com/watch?v=bHTlQ61AaIE

    The batch file will only work if each video has the same audio/subtitle options, but it's the best I've come up with using a batch file.
    Quote Quote  
  7. batch expert Endoro's Avatar
    Join Date
    Dec 2013
    Location
    Bozen
    Search PM
    Originally Posted by BearTanks View Post
    The batch file will only work if each video has the same audio/subtitle options,
    For very simple tasks you do not need a script, just only one line in the cmd window. Example to remove the second audio track (track ID 2) and the second subtitle track (track ID 4):
    Code:
    for %a in (*.mkv) do @mkvmerge -o "output/%~a" --audio-tracks !2 --subtitle-tracks !4 "%~a"
    Create the folder "output" before running. The track ID can be obtained using the command 'mkvmerge --identify "video.mkv"'.
    Last edited by Endoro; 2nd Feb 2014 at 04:12.
    Quote Quote  
  8. Originally Posted by fryk View Post
    I adopted it for the Windows cmd shell ('batch') and added subtitle support.
    Tested with Windows 8.

    Code:
     
    @ECHO OFF &SETLOCAL
    TITLE Recursive remove audio and subtitle tracks by language from MKV video files
    rem search for MKVs in all "StartFolder\Subfolders", not in "Startfolder" itself
    SET "StartFolder=."
    rem example to keep English and German audio tracks, please note the colon in front of the language code
    SET "AudioTracksToKeep=:eng:ger"
    rem example to keep Spanish and French subtitle tracks, please note the colon in front of the language code
    SET "SubsTracksToKeep=:spa:fre"
    rem the file name variable must be global for some reasons
    SET "MKVFile="
    
    FOR /f "DELIMS=" %%a IN ('DIR /b /s /a-d "%StartFolder%\*.mkv"') DO SET "MKVFile=%%~a"&CALL:scanmkv
    GOTO:EOF
    
    :scanmkv
    SETLOCAL
    ECHO(
    ECHO(Scanning "%MKVFile%" for unwanted tracks.
    (FOR /l %%b IN (1 1 45) DO <nul SET /p "=-")&ECHO(
    
    SET /a AudioTrackCount=0
    SET /a NumberKeepAudio=0
    SET /a NumberDiscardAudio=0
    
    rem get the number of audio tracks
    FOR /f %%a IN ('mkvmerge --ui-language en -i "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: audio"') DO SET /a AudioTrackCount+=1
    ECHO(Number of audio tracks: %AudioTrackCount%
    rem always keep at least one audio track
    IF %AudioTrackCount% LSS 2 GOTO:subscan
    
    rem get the audio tracks to keep
    SET "KeepAudioSearchString=%AudioTracksToKeep::= language:%"
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: audio"^|FINDSTR /ri "%KeepAudioSearchString%"') DO (
        SET /a NumberKeepAudio+=1
        CALL SET "AudioIdentKeepLine=%%AudioIdentKeepLine%%,%%a"
    )
    IF NOT DEFINED AudioIdentKeepLine SET "AudioIdentKeepLine= ^<none^>"
    ECHO(ID of %NumberKeepAudio% track(s) to keep: %AudioIdentKeepLine:~1%
    IF %NumberKeepAudio%==0 GOTO:subscan
    
    rem get the audio tracks to reject
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: audio"^|FINDSTR /riv "%KeepAudioSearchString%"') DO (
        SET /a NumberDiscardAudio+=1
        CALL SET "AudioIdentDiscardLine=%%AudioIdentDiscardLine%%,%%a"
    )
    IF NOT DEFINED AudioIdentDiscardLine SET "AudioIdentDiscardLine= ^<none^>"
    ECHO(ID of %NumberDiscardAudio% track(s) to reject: %AudioIdentDiscardLine:~1%
    IF %NumberDiscardAudio%==0 GOTO:subscan
    
    :subscan
    SET /a SubsTrackCount=0
    SET /a NumberKeepSubs=0
    SET /a NumberDiscardSubs=0
    
    rem get the number of subtitle tracks
    FOR /f %%a IN ('mkvmerge --ui-language en -i "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: subtitles"') DO SET /a SubsTrackCount+=1
    ECHO(Number of subtitle tracks: %SubsTrackCount%
    IF %SubsTrackCount% EQU 0 GOTO:muxing
    
    rem get the subtitle tracks to keep
    SET "KeepSubsSearchString=%SubsTracksToKeep::= language:%"
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: subtitles"^|FINDSTR /ri "%KeepSubsSearchString%"') DO (
        SET /a NumberKeepSubs+=1
        CALL SET "SubsIdentKeepLine=%%SubsIdentKeepLine%%,%%a"
    )
    IF NOT DEFINED SubsIdentKeepLine SET "SubsIdentKeepLine= ^<none^>"
    ECHO(ID of %NumberKeepSubs% track(s) to keep: %SubsIdentKeepLine:~1%
    IF %NumberKeepSubs%==0 GOTO:muxing
    
    rem get the subtitle tracks to reject
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: subtitles"^|FINDSTR /riv "%KeepSubsSearchString%"') DO (
        SET /a NumberDiscardSubs+=1
        CALL SET "SubsIdentDiscardLine=%%SubsIdentDiscardLine%%,%%a"
    )
    IF NOT DEFINED SubsIdentDiscardLine SET "SubsIdentDiscardLine= ^<none^>"
    ECHO(ID of %NumberDiscardSubs% track(s) to reject: %SubsIdentDiscardLine:~1%
    IF %NumberDiscardSubs%==0 GOTO:muxing
    
    :muxing
    IF %NumberDiscardAudio%==0 IF %NumberDiscardSubs%==0 ECHO(Nothing to do.&EXIT /b
    IF %NumberDiscardAudio% NEQ 0 SET "CommandLine=-a %AudioIdentKeepLine:~1%"
    IF %NumberDiscardSubs% NEQ 0 SET "CommandLine=%Commandline% -s %SubsIdentKeepLine:~1%"
    
    rem make a backup copy of the MKV
    FOR %%a IN ("%MKVFile%") DO SET "MKVBackupFile=%%~na.bak%%~xa"
    ECHO(Building "%MKVBackupFile%"
    REN "%MKVFile%" "%MKVBackupFile%" || (ECHO(Error renaming to "%MKVBackupFile%"&EXIT /b)
    
    rem build the new MKV
    FOR %%a IN ("%MKVFile%") DO SET "MKVBackupFile=%%~dpa%MKVBackupFile%"
    ECHO(REMuxing "%MKVFile%"
    mkvmerge -o "%MKVFile%" %Commandline% "%MKVBackupFile%"
    EXIT /b
    The code might crash, if you use characters like !%^ or similar in file or path names.
    Thanks, this worked great but I had to change 1 line near the end to
    Code:
    FOR %%a IN ("%MKVFile%") DO SET "MKVBackupFile=%MKVBackupFile%"
    , the %%~dpa part didn't work for me.

    I have limited experience in batch programming for DOS but also changed the beginning of the script to be able to drag and drop a file the batch file and then looped it to handle multiple files.

    like this:

    Code:
    :LOOP
    FOR /f "DELIMS=" %%a IN ('DIR /b /s /a-d %1') DO SET "MKVFile=%%~a"&CALL:scanmkv
    SHIFT
    IF NOT (%1)==() GOTO LOOP
    GOTO:EOF
    Maybe there are more elegant solutions than my changes but it works here at the moment, I put the batch file in the same folder as the files to be converted.
    Last edited by Pirum; 24th Sep 2014 at 01:40.
    Quote Quote  
  9. Member
    Join Date
    Jul 2015
    Location
    Australia
    Search Comp PM
    Ok.
    So i have had a turn at modding the script too.

    a. I've added a Path function, so you only need to have the ".bat" file located in the folder you are working on, you wont need to have the mkvmerge.exe executable file there anymore. You will need to modify this path setting to the location of your mkvmerge.exe program.

    Code:
    PATH "mkvmerge=C:\Program Files\MKVToolNix\mkvmerge.exe"
    b. And i have added a command to delete the ".bak" file once the muxing has finished doing its thing. That way you don't get recurring .bak files created every time you run the .bat file in your folder. Be warned, as the CMD line is doing the deleting, these deleted backup files wont be recoverable from the Trash Can anymore.

    Code:
    rem delete backup mvk file
    ECHO(Deleteing "%MKVBackupFile%"
    DEL %MKVBackupFile%
    Code:
    @ECHO OFF &SETLOCAL
    TITLE Recursive remove audio and subtitle tracks by language from MKV video files
    rem search for MKVs in all "StartFolder\Subfolders", not in "Startfolder" itself
    SET "StartFolder=."
    rem example to keep English and German audio tracks, please note the colon in front of the language code
    SET "AudioTracksToKeep=:eng"
    rem example to keep Spanish and French subtitle tracks, please note the colon in front of the language code
    SET "SubsTracksToKeep=:eng"
    rem the file name variable must be global for some reasons
    SET "MKVFile="
    PATH "mkvmerge=C:\Program Files\MKVToolNix\mkvmerge.exe"
    
    FOR /f "DELIMS=" %%a IN ('DIR /b /s /a-d "%StartFolder%\*.mkv"') DO SET "MKVFile=%%~a"&CALL:scanmkv
    GOTO:EOF
    
    :scanmkv
    SETLOCAL
    ECHO(
    ECHO(Scanning "%MKVFile%" for unwanted tracks.
    (FOR /l %%b IN (1 1 45) DO <nul SET /p "=-")&ECHO(
    
    SET /a AudioTrackCount=0
    SET /a NumberKeepAudio=0
    SET /a NumberDiscardAudio=0
    
    rem get the number of audio tracks
    FOR /f %%a IN ('mkvmerge --ui-language en -i "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: audio"') DO SET /a AudioTrackCount+=1
    ECHO(Number of audio tracks: %AudioTrackCount%
    rem always keep at least one audio track
    IF %AudioTrackCount% LSS 2 GOTO:subscan
    
    rem get the audio tracks to keep
    SET "KeepAudioSearchString=%AudioTracksToKeep::= language:%"
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: audio"^|FINDSTR /ri "%KeepAudioSearchString%"') DO (
        SET /a NumberKeepAudio+=1
        CALL SET "AudioIdentKeepLine=%%AudioIdentKeepLine%%,%%a"
    )
    IF NOT DEFINED AudioIdentKeepLine SET "AudioIdentKeepLine= ^<none^>"
    ECHO(ID of %NumberKeepAudio% track(s) to keep: %AudioIdentKeepLine:~1%
    IF %NumberKeepAudio%==0 GOTO:subscan
    
    rem get the audio tracks to reject
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: audio"^|FINDSTR /riv "%KeepAudioSearchString%"') DO (
        SET /a NumberDiscardAudio+=1
        CALL SET "AudioIdentDiscardLine=%%AudioIdentDiscardLine%%,%%a"
    )
    IF NOT DEFINED AudioIdentDiscardLine SET "AudioIdentDiscardLine= ^<none^>"
    ECHO(ID of %NumberDiscardAudio% track(s) to reject: %AudioIdentDiscardLine:~1%
    IF %NumberDiscardAudio%==0 GOTO:subscan
    
    :subscan
    SET /a SubsTrackCount=0
    SET /a NumberKeepSubs=0
    SET /a NumberDiscardSubs=0
    
    rem get the number of subtitle tracks
    FOR /f %%a IN ('mkvmerge --ui-language en -i "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: subtitles"') DO SET /a SubsTrackCount+=1
    ECHO(Number of subtitle tracks: %SubsTrackCount%
    IF %SubsTrackCount% EQU 0 GOTO:muxing
    
    rem get the subtitle tracks to keep
    SET "KeepSubsSearchString=%SubsTracksToKeep::= language:%"
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: subtitles"^|FINDSTR /ri "%KeepSubsSearchString%"') DO (
        SET /a NumberKeepSubs+=1
        CALL SET "SubsIdentKeepLine=%%SubsIdentKeepLine%%,%%a"
    )
    IF NOT DEFINED SubsIdentKeepLine SET "SubsIdentKeepLine= ^<none^>"
    ECHO(ID of %NumberKeepSubs% track(s) to keep: %SubsIdentKeepLine:~1%
    IF %NumberKeepSubs%==0 GOTO:muxing
    
    rem get the subtitle tracks to reject
    FOR /f "TOKENS=3DELIMS=: " %%a IN ('mkvmerge --ui-language en --identify-verbose "%MKVFile%"^|FINDSTR /rbic:"Track ID [0-9][0-9]*: subtitles"^|FINDSTR /riv "%KeepSubsSearchString%"') DO (
        SET /a NumberDiscardSubs+=1
        CALL SET "SubsIdentDiscardLine=%%SubsIdentDiscardLine%%,%%a"
    )
    IF NOT DEFINED SubsIdentDiscardLine SET "SubsIdentDiscardLine= ^<none^>"
    ECHO(ID of %NumberDiscardSubs% track(s) to reject: %SubsIdentDiscardLine:~1%
    IF %NumberDiscardSubs%==0 GOTO:muxing
    
    :muxing
    IF %NumberDiscardAudio%==0 IF %NumberDiscardSubs%==0 ECHO(Nothing to do.&EXIT /b
    IF %NumberDiscardAudio% NEQ 0 SET "CommandLine=-a %AudioIdentKeepLine:~1%"
    IF %NumberDiscardSubs% NEQ 0 SET "CommandLine=%Commandline% -s %SubsIdentKeepLine:~1%"
    
    rem make a backup copy of the MKV
    FOR %%a IN ("%MKVFile%") DO SET "MKVBackupFile=%%~na.bak%%~xa"
    ECHO(Building "%MKVBackupFile%"
    REN "%MKVFile%" "%MKVBackupFile%" || (ECHO(Error renaming to "%MKVBackupFile%"&EXIT /b)
    
    rem build the new MKV
    FOR %%a IN ("%MKVFile%") DO SET "MKVBackupFile=%MKVBackupFile%"
    ECHO(REMuxing "%MKVFile%"
    mkvmerge -o "%MKVFile%" %Commandline% "%MKVBackupFile%"
    
    rem delete backup mvk file
    ECHO(Deleteing "%MKVBackupFile%"
    DEL %MKVBackupFile%
    EXIT /b
    Last edited by yobrevar; 25th Jul 2015 at 02:54. Reason: attachment
    Quote Quote  
  10. Originally Posted by yobrevar View Post
    Ok.
    So i have had a turn at modding the script too.
    Hey yobrevar,

    When I try to run your version, I get an error saying something along the lines of no command, program, bat file for mkvmerge. I've confirmed that I have pasted the correct path into the mkvmerge.exe PATH line.

    I'm trying to run it on Windows 10, 64 Bit.

    Any suggestions?
    Quote Quote  
  11. Member
    Join Date
    Jul 2016
    Location
    Austin, TX, USA
    Search PM
    I've created a simple .net Application that will recursively go through the destination folder, check the lang file on all tracks (video/audio/subtitles) on all mkv files and remove any that aren't specified. It makes a temporary file called Work_filename and then deletes the original and renames the fixed file.

    Example
    RemoveunwantedTracks.exe -d "Folder to look in''s full path" -m "Folder where mkvmerge is" -l language wanted
    RemoveunwantedTracks.exe -d "d:\TV Shows\TV Show 1" -m "D:\Tools\MKVtoolnix" -l eng

    You can specify multiple directories and languages if wanted. also can turn off recursive mode. (running with -h will give you a list of commands.

    Hope this helps anyone. Enjoy.

    -Chuck DDB
    Image Attached Files
    Last edited by ChuckDDB; 11th Jul 2016 at 23:05. Reason: Misspelling
    Quote Quote  
  12. Originally Posted by ChuckDDB View Post
    I've created a simple .net Application that will recursively go through the destination folder, check the lang file on all tracks (video/audio/subtitles) on all mkv files and remove any that aren't specified. It makes a temporary file called Work_filename and then deletes the original and renames the fixed file.

    Example
    RemoveunwantedTracks.exe -d "Folder to look in''s full path" -m "Folder where mkvmerge is" -l language wanted
    RemoveunwantedTracks.exe -d "d:\TV Shows\TV Show 1" -m "D:\Tools\MKVtoolnix" -l eng

    You can specify multiple directories and languages if wanted. also can turn off recursive mode. (running with -h will give you a list of commands.

    Hope this helps anyone. Enjoy.

    -Chuck DDB
    That's exactly what I was looking for!

    My files have 4 tracks (2 eng, 1 por and 1 jpn) unfortunately I could'n get it to work while keeping the two last. I tried "-l por, jpn" and "-l por jpn" to no avail :/
    Quote Quote  
  13. LOVE this program! Thank you for making it!

    1. A couple small things I might add to it; when there's some error, for example, if the path to mkvmerge folder is bad, it shows the crash dialog, then pressing continue on it show all of the ugly dev error code that looks like jibberish to your average Joe. Adding a Try/Catch to that, and changing the error stuff to Laymen's Terms (i.e. "Bad Path to the MKVTools Folder") instead would be much nicer.

    2. When doing the /h, adding in the description, and example usage (even just pasting exactly what you wrote in your post on it) in addition to what it already shows, would be great. Then it's all in one handy lil package. No ReadMe.txt or anything needing to sit next to it in it's folder.

    3. Log all changes to a log file, so they can be reviewed later.

    Thanks!

    P.S. If you don't want to take time out to do it, I can do it if the source is available.
    Last edited by NukeyDoo; 23rd Sep 2016 at 00:06.
    Quote Quote  
  14. Member
    Join Date
    Jul 2016
    Location
    Austin, TX, USA
    Search PM
    Sorry, but I haven't been on here for awhile.

    Here is the Source Code if anyone wants to change anything, I believe something was changed in mkvmerge v15 that broke the removal of mismatched subtitle languages, but I haven't had time to look into anything.

    Enjoy (It's a VS 2015 Solution)

    -Chuck
    Image Attached Files
    Quote Quote  
  15. Pretty simple with current version of mkvmerge. Just tell it to copy only english audio/subtitle tracks to the new mkv file. For english, use eng. For any other language, refer to ISO639-2 language code

    Using programming language agnostic concept . Variables are between {} :

    Code:
    set {audio} as any of these :
    for english audio = -a "eng" for english and french audio = -a "eng,fre"
    set {subtitle} as any of these :
    for english sub = -s "eng" for english and french sub = -s "eng,fre" for no sub (delete all) = --no-subtitles to keep all subs, let variable empty.
    mkvmerge --title "[filename|noext ]" --output "path\new file with english tracks only.mkv" {$audio} {$subtitle} "(" "file to process.mkv" ")"
    See documentation and search the page for parenthesis to understand why I use them to handle file to process. Itís my own habit to prevent unwanted behavior. Youíre not forced to use them.

    To sum this up, the simplest command to use to keep english audio track only would be :

    Code:
    mkvmerge --output "path\new file with english tracks only.mkv" -a "eng" "file to process.mkv"
    Last edited by freMea; 28th Dec 2018 at 12:37.
    Quote Quote  



Similar Threads