Well, VHS capturing Mostly cartoons, having some questions:)

[Mr_khyron]

Well mostly use the PC for everything, but compatibility is an important subject indeed, will probably make 2 versions for what i am unsure of then, ogg and aac, but i can see there is Nero aac, and Faac, which is gives best result?

Nero aac

[zerowalker]

Okay, thanks

[zerowalker]

Oh, another thing, i saw a thing called Open GOP, i have read about it, and as i understand it´s a good thing, but not all decoders support it.
Can anyone spread some light over what the advantages it has?

Edit: what is the best way to prevent this weird looking thing (look under the girl)
That thing appears before it has happened, and looks almost like the temporal filter thing.
I think it´s because the source is/was interlaced, and that picture is from a clip where i have done MCTemporalDensios Very High, and this

SetMTMode(6,4)
AVISource("C:\Alice I Underlandet - Gammal\Test_1.avi")
Crop(0,0,0,-4)
Dehalo_Alpha(rx=2,ry=2,darkstr=1.1,brightstr=1.1)
Santiag()
AwarpSharp2(depth=6)
Toon(strength=0.4)
LSFMod(strength=50)
TTempSmooth(maxr=5, lthresh=12, cthresh=4, strength=5)
SmoothLevels(23,1.1,255,0,255)
SmoothTweak(contrast=1.0, hue1=6, hue2=-11, saturation=1.1)
MergeChroma(awarpsharp2(depth=45))
Deen()
DFTTest(sigma=32,sigma2=32, lsb=true)
msb = last.Dither_get_msb ()
lsb = last.Dither_get_lsb ()
DitherPost (msb, lsb, stacked=false)
GradFun3()

So i never Deinterlaced it, so what is the way to go, should i deinterlace first, and then denoise, or can you remove it after, or is there any filter i should have been used?

Thanks as always!

[jagabo]

Open GOPs are when the B frames at the end of a GOP reference the I frame of the next GOP. They increase compression efficiency a tiny bit.

The ghost under the girls where her feet will be in the next frame. They are a result of the heavy temporal filtering.

[zerowalker]

Ah, thanks!
But should i just skip deinterlacing as i have?
As you have seen the script i am currently playing around with, it´s giving good results.
But as said, i do MCTemporalDenoising Very High, before using the above scripts (with adjustments for my taste).

But i do have a problem i will be trying to solve, hopefully i will ,else i will bring it up later on

[themaster1]

All infos about x264 settings here: http://mewiki.project357.com/wiki/X264_Settings

[zerowalker]

Yeah have read much there, but some things are just now written in a way which makes me understand it completely.
I don´t understand the English language completely, but i do understand it well. So i think that it´s better to ask if you wonder about it, then guessing through if you get my meaning

[jagabo]

But should i just skip deinterlacing as i have?

Your frames have no comb artifacts so it's safe to consider them progressive.

As you have seen the script i am currently playing around with, it´s giving good results.
But as said, i do MCTemporalDenoising Very High, before using the above scripts (with adjustments for my taste).

Temporal denoisers work by averaging together pixels from multiple frames. When the pixels in the surrounding frames are very different they don't use those pixels because it's assumed something has moved and you don't want to get ghosting. The more noise there is in your video the stronger the denoising you have to use. That means the threshold of not averaging gets higher. So in areas of low contrast you start getting ghosting. That's what you're seeing. You can use less strong settings in the denoiser to reduce the ghosting but then more noise will be left in the picture.

[zerowalker]

Ah thanks, that clears some things up for me!
Grateful as always

Edit: Is there anyway to remove it afterwards, some filtering maybe?
I am sure there isn´t such an easy way though, but worth asking

[poisondeathray]

Difficult to remove after, you would probably have to remove it before

As jagabo said - it's likely a temporal artifact, so either adjust the mctd settings, or ttempsmooth settings

It can also be from not removing the noise completely before temporal smoothing so sometimes stronger spatial denoise actually helps instead of weaker. But it can also be from duplicate frames if you didn't decimate (the underlying consecutive frames are supposed the same, but there is a slight variations in noise pattern on the duplicate, this causes issue with temporal filtering)

[zerowalker]

Okay, will try to find the reason, and play around with the settings, thanks

[poisondeathray]

If you've found ideal settings that work for most of the video, but only certain sections have the issue , you can apply different filter settings to different sections (e.g. divide up into sections by using Trim() ) . Because changing the settings globally, might screw up the other sections

[zerowalker]

Ah, i was gonna ask for a way to do that, how do you use trim with a filter?
Can you show an example script please?

[poisondeathray]

a=avisource()

a
#filterstack 1
b=last

a
#filterstack 2
c=last


b.Trim(0,100) ++ c.Trim(101,200) ++ b.Trim(201,300)


There are many ways to do this; In this example, "filterstack 1" is applied to frames 0-100, and 201-300, "filterstack 2" is applied to frames 101-200

If you haven't already, use avspmod to preview your scripts. pushf5 to preview. You can compare script versions in multiple tabs (hit the number keys to swap). This helps you determine what settings and values or filter combinations might be "ideal"

[jagabo]

You can try using stronger spacial filtering before the temporal filter(s). That will make it easier for the temporal filters to differentiate inter-frame noise from detail (ie, you can use a less strong temporal filter). Unfortunately, stronger spacial filtering will reduce small intra-frame details too.

I don't think you'll notice a little ghosting like that at normal playback speed.

[Firesledge]

The ghosting most likely comes from this line :

DFTTest(sigma=32,sigma2=32, lsb=true)

Dfttest is a spatio-temporal denoiser working on 5 frames (unless otherwise specified) without any protection against ghosting. You should do a motion compensation with the MVTools2 to use it safely.

BTW I noticed you apply GradFun3 just after dfttest, this is suboptimal to make it output 16 bit per component, then immediately dither it. You could just have the dither done by dfttest: "dfttest (parmeters, dither=1)". Or do the whole process in 16 bits and use SmoothGrad() before dithering, instead of GradFun3:

# Motion compensation on frames -2...+2
super = MSuper ()
vf2 = super.MAnalyse (isb=false, delta=2, overlap=4)
vf1 = super.MAnalyse (isb=false, delta=1, overlap=4)
vb1 = super.MAnalyse (isb=true,  delta=1, overlap=4)
vb2 = super.MAnalyse (isb=true,  delta=2, overlap=4)
cf2 = MCompensate (super, vf2, thSAD=400)
cf1 = MCompensate (super, vf1, thSAD=400)
cb1 = MCompensate (super, vb1, thSAD=400)
cb2 = MCompensate (super, vb2, thSAD=400)

# dfttest on motion-compensated clip
Interleave (cf2, cf1, last, cb1, cb2)
dfttest (sigma=32, sigma2=32, tbsize=5, lsb=true)
SelectEvery (5, 2)

# Gradient smoothing
presmooth = last
SmoothGrad (radius=20, thr=0.15)
SmoothGrad (radius=12, thr=0.25, ref=presmooth)

# Back to 8 bits, ordered dithering
DitherPost ()

[zerowalker]

Okay, so i should have dfttest
( sigma=32,sigma2=32, lsb=true, dither=1) ?

And i don´t understand what the motion compensation does, i do know the word though.
And don´t really know what Dither does, i think it had something to do with improving the image, as in gif pictures or something.
I mostly played around with the things i didn´t noticed what they did and just kept them. But what do you recommend i do?

And if you zoom in on the left part of the picture, you can see that the pixels are in an a sort of formation, don´t reallly know how to explain it. but it does happen in the other movie too, is that good or bad?

[jagabo]

And i don´t understand what the motion compensation does, i do know the word though.

Instead of looking at the same location in the earlier and later frames it looks for parts of the picture that have moved and compensates for that motion. For example, if the frame shifted left by four pixels it averages pixels at (x-4,y) instead of (x,y).

And don´t really know what Dither does, i think it had something to do with improving the image, as in gif pictures or something.

That's basically adding noise back to the image to reduce posterization.
http://en.wikipedia.org/wiki/Ordered_dithering

And if you zoom in on the left part of the picture, you can see that the pixels are in an a sort of formation, don´t reallly know how to explain it. but it does happen in the other movie too, is that good or bad?

That's the ordered dither.

[zerowalker]

Okay, so i should have Dither, i tried using dfttest(dither=1) and removing Gradfun3(), though i didn´t see any difference i think.
But Dither is good. Don´t really know how to use the Motion Compensation as i don´t understand the codes written, but as it prevents ghosting it would be nice to use, but does it have any bad effects?

[Firesledge]

Don´t really know how to use the Motion Compensation as i don´t understand the codes written, but as it prevents ghosting it would be nice to use

Just replace the dfttest...gradfun3 lines with the script I provided in my previous post:

SetMTMode(6,4)
AVISource("C:\Alice I Underlandet - Gammal\Test_1.avi")
Crop(0,0,0,-4)
Dehalo_Alpha(rx=2,ry=2,darkstr=1.1,brightstr=1.1)
Santiag()
AwarpSharp2(depth=6)
Toon(strength=0.4)
LSFMod(strength=50)
TTempSmooth(maxr=5, lthresh=12, cthresh=4, strength=5)
SmoothLevels(23,1.1,255,0,255)
SmoothTweak(contrast=1.0, hue1=6, hue2=-11, saturation=1.1)
MergeChroma(awarpsharp2(depth=45))
Deen()

# Motion compensation on frames -2...+2
super = MSuper ()
vf2 = super.MAnalyse (isb=false, delta=2, overlap=4)
vf1 = super.MAnalyse (isb=false, delta=1, overlap=4)
vb1 = super.MAnalyse (isb=true,  delta=1, overlap=4)
vb2 = super.MAnalyse (isb=true,  delta=2, overlap=4)
cf2 = MCompensate (super, vf2, thSAD=400)
cf1 = MCompensate (super, vf1, thSAD=400)
cb1 = MCompensate (super, vb1, thSAD=400)
cb2 = MCompensate (super, vb2, thSAD=400)

# dfttest on motion-compensated clip
Interleave (cf2, cf1, last, cb1, cb2)
dfttest (sigma=32, sigma2=32, tbsize=5, lsb=true)
SelectEvery (5, 2)

# Gradient smoothing
presmooth = last
SmoothGrad (radius=20, thr=0.15)
SmoothGrad (radius=12, thr=0.25, ref=presmooth)

# Back to 8 bits, ordered dithering
DitherPost ()

but does it have any bad effects?

It slows down the script and takes more RAM.

[zerowalker]

Okay, will give it a try on a movie after i do a noise reducer, so it will take a while:P
Thanks for helping out!

[themaster1]

I'm trying your script now Firesledge, it assume the source is progressive, where you would place the separatefields & weave for an interlaced source in your script because i'm getting an error...

[poisondeathray]

I'm trying your script now Firesledge, it assume the source is progressive, where you would place the separatefields & weave for an interlaced source in your script because i'm getting an error...

I think you would do it the same as any other filter for interlaced footage, ie. apply filters to even and odd fields then interleave & weave

e,g.

 
whateversource()
c=last
 
 
 
#even fields
# Motion compensation on frames -2...+2
even = c.SeparateFields().SelectEven()
super_even=even.MSuper()
vf2 = super_even.MAnalyse (isb=false, delta=2, overlap=4)
vf1 = super_even.MAnalyse (isb=false, delta=1, overlap=4)
vb1 = super_even.MAnalyse (isb=true,  delta=1, overlap=4)
vb2 = super_even.MAnalyse (isb=true,  delta=2, overlap=4)
cf2 = MCompensate (even, super_even, vf2, thSAD=400)
cf1 = MCompensate (even, super_even, vf1, thSAD=400)
cb1 = MCompensate (even, super_even, vb1, thSAD=400)
cb2 = MCompensate (even, super_even, vb2, thSAD=400)
 
# dfttest on motion-compensated clip
Interleave (cf2, cf1, even, cb1, cb2)
dfttest (sigma=32, sigma2=32, tbsize=5, lsb=true)
SelectEvery (5, 2)
 
# Gradient smoothing
presmooth = last
SmoothGrad (radius=20, thr=0.15)
SmoothGrad (radius=12, thr=0.25, ref=presmooth)
 
# Back to 8 bits, ordered dithering
DitherPost ()
filtered_even=last
 
 
 
 
 
#odd fields
# Motion compensation on frames -2...+2
odd = c.SeparateFields().SelectOdd()
super_odd=odd.MSuper()
 
vf2 = super_odd.MAnalyse (isb=false, delta=2, overlap=4)
vf1 = super_odd.MAnalyse (isb=false, delta=1, overlap=4)
vb1 = super_odd.MAnalyse (isb=true,  delta=1, overlap=4)
vb2 = super_odd.MAnalyse (isb=true,  delta=2, overlap=4)
cf2 = MCompensate (odd, super_odd, vf2, thSAD=400)
cf1 = MCompensate (odd, super_odd, vf1, thSAD=400)
cb1 = MCompensate (odd, super_odd, vb1, thSAD=400)
cb2 = MCompensate (odd, super_odd, vb2, thSAD=400)
 
# dfttest on motion-compensated clip
Interleave (cf2, cf1, odd, cb1, cb2)
dfttest (sigma=32, sigma2=32, tbsize=5, lsb=true)
SelectEvery (5, 2)
 
# Gradient smoothing
presmooth = last
SmoothGrad (radius=20, thr=0.15)
SmoothGrad (radius=12, thr=0.25, ref=presmooth)
 
# Back to 8 bits, ordered dithering
DitherPost ()
filtered_odd=last
 
 
 
 
 
 
Interleave(filtered_even, filtered_odd)
Weave()

[themaster1]

What version of dfttest do i need cos i have an error... and i thought i had the latest

"there is no argument lsb=true"

Anyway if i remove , lsb=true it's processing half the video only strange

[zerowalker]

Hmm dunno, i downloaded and replaced till it work, sadly don´t know what Isb and the likes does, but i have seen the problem with half video though, but only if i remove stuff like you did

[poisondeathray]

you need dfttest-1.8-mod16b from the dither package

lsb= least significant bytes ; it's working with 2 x 8bit images

http://ldesoras.free.fr/prod.html#src_ditheravsi

[themaster1]

It's my bad i've linked the wrong (old) dll in my script, working now.

[zerowalker]

To take another step, once i want to encode this, for example Alice or the other one Digimon, which has 2d and 3d animations if some of you have seen it, what settings do you recommend in x264 (as in tunning), i have given Alice Animation, but not sure if it is right as the vhs rip is "wavy" so maybe Animation isn´t the right tunning as there isn´t much still images and low detail, or maybe i am correct.

Please consider i have Cartoon and normal movies, what is recommended overall for vhs rips etc?
Thanks as Always

[jagabo]

I did a quick google search to find out what Digimon was and found this:

http://www.watchdigimonepisodes.com/

I started watching one episode and the quality was pretty good. At least some episodes are explicitly available for download.

[zerowalker]

yeah seems so