horizontal color bar

[themaster1]

I can't remember exactly but there was a script which could get rid of this kind of defect

[jagabo]

This (mostly) works for a static bar:

ImageSource("ugk-blue_bar-crop.jpg") 
ConvertToYUY2()
top = Crop(0,0,width,50)
bot = Crop(0,50,width,-0)
bot = MergeChroma(bot, bot.Invert())
StackVertical(top,bot)

[themaster1]

I've found the magic script again in my archives , have a look below Jagabo but i have a problem a small horizontal line is still present if you can give me a hand to tweak that:

imagesource ("blabla.jpg").converttoyv12()
# X1 is left, Y1 is top, X2 is right, Y2 is bottom
X1 = 0
Y1 = 0
X2 = 720 # for a 720 wide horizontal bar , change accordingly
Y2 = 32 # for a top 32 pixels in height horizontal bar, change accordingly
# Make the values MOD4
X1 = X1 - (X1 % 4)
Y1 = Y1 - (y1 % 4)
X2 = (X2 + 3) / 4 * 4
Y2 = (Y2 + 3) / 4 * 4
##
Active = crop(X1,Y1,X2-X1,Y2-Y1)
Above = Y1 > 0 ? crop(0,0,width(),Y1) : NOP
Below = Y2 < height() ? crop(0,Y2,width(),height()-Y2) : NOP
Left = X1 > 0 ? crop(0,Y1,X1,Y2-Y1) : NOP
Right = X2 < width() ? crop(X2,Y1,width()-X2,Y2-Y1) : NOP
Last = Active
# INVERT HUES:
input=last
U = UtoY().Invert()
V = VtoY().Invert()
YtoUV(U, V, last)
#####
IsClip(Left) ? StackHorizontal(Left, Last) : NOP
IsClip(Right) ? StackHorizontal(Last, Right) : NOP
IsClip(Above) ? StackVertical(Above, Last) : NOP
IsClip(Below) ? StackVertical(Last, Below) : NOP
return Last

The image i'm working on:

Result:

[jagabo]

That's basically the same thing I did except for the reversal of the colors. And the longer script has the ability to split right/left in addition to top/bottom.

The remaining discolored bar is there because the transition from cyan to brown isn't sharp. No matter where you split the video a little bar will be left. I'd fill the bar with an overlay of colors interpolated from above and below.

[themaster1]

I'd fill the bar with an overlay of colors interpolated from above and below.

How ould you script that jagabo ?

[jagabo]

Something like this:

YPOS = 34

ImageSource("Cyan_bar.jpg", start=0, end=23, fps=23.976) 
ConvertToYV12()

# first fix the top
top = Crop(0,0,width,YPOS)
top = MergeChroma(top, top.Invert())
bot = Crop(0,YPOS,width,-0)
StackVertical(top,bot)

# then fix the remaining strip
top = Crop(0, YPOS-6, width,4) # four lines above
bot = Crop(0, YPOS+2, width,4) # four lines below
patch=StackVertical(top,bot).Blur(0,1.0).Crop(0,2,-0,-2)
MergeChroma(last, Overlay(last,patch,x=0,y=YPOS-2))

Feathering the edges with an alpha mask will probably look better in moving shots.